Please help! I've been struggling for weeks!

I've tried a thousand ways to create a recordset and the closest i've got is receiving the error 'permission denied'. I say the closest because this would indicate that the coding is correct but something else has gone wrong?

Ideally i would like to return a list of postcode sectors within a 20 mile drivetime of a full postcode. However, at present i would be happy to return anything postcode related in a recordset.

From my searching, the most basic recordset should be possible from the below. This returns the 'Permission Denied' error.

Set objMap = objapp.ActiveMap
Set objDataSet = objMap.DataSets.GetDemographics(geoCountryUnitedKi ngdom)

Set rst = objDataSet.QueryAllRecords

Thanks for your help,
sugarflux

Hi,

Which line is offending ? The QueryAllRecords, or the GetDemoGraphics ?

The error is because all the query methods return an error when used on a dataset created by a demographic.

To rectify this, you'll need to create a pushpin map for postcode districts, then draw your radius on the selected location, then call QueryShape().

I created a postcode district text file for you, posted at
PostalDistricts.txt
which you'll want to import as a pushpin map.

After that map is loaded, you can use the following VB6/VBA routine to get the postcode districts within a radius of a searched postcode.

Code:

Private Function GetPostalDistrictsWithinRadius( _
        ByVal strPostalCode As String, _
        ByVal Radius As Single) As String()
    Dim locCtr As MapPoint.Location
    Set locCtr = objMap.FindAddressResults( _
        , , , , strPostalCode, "United Kingdom")(1)
    locCtr.GoTo
    objMap.Altitude = Radius + 1
    objMPApp.Units = geoMiles
    Dim shp As MapPoint.Shape
    Set shp = objMap.Shapes.AddShape( _
        geoShapeRadius, locCtr, Radius, Radius)
    shp.Line.ForeColor = 1
    shp.Line.Weight = 0.25
    shp.Fill.Visible = False
    Dim ds As MapPoint.DataSet
    Set ds = objMap.DataSets(1)
    Dim rs As MapPoint.Recordset
    Set rs = ds.QueryShape(shp)
    Dim strPCD() As String
    Dim i As Integer
    Do While Not rs.EOF
        i = i + 1
        ReDim Preserve strPCD(i)
        strPCD(i) = rs.Location.Name
        rs.MoveNext
    Loop
    shp.Delete
    GetPostalDistrictsWithinRadius = strPCD
End Function

You can call the method and iterate through the returned results using something like

Code:

Private Sub Command1_Click()
    Dim s() As String
    s = GetPostalDistrictsWithinRadius(Text1.Text, 20)
    Dim t As Variant
    For Each t In s
        Debug.Print t
    Next
End Sub

HTH
Paul

Thanks Paul. I really appreciate your help.

This looks great - just a couple of minor problems.

First off, i need to be working at sector level. I was under the impression that i wouldn't need an external file to work with - surely these postcodes are already present in Mappoint ??

Secondly if it is the case that the file needs importing to work with the recordset, do you have any code for importing programmatically please?

I have tried the following:

Set objDataSet = objApp.ActiveMap.DataSets.ImportData("C:\PostalDis tricts.txt", 1, geoCountryUnitedKingdom, geoDelimiterComma, 0)

and receive the error:
Cannot connect with the specified datasourcemoniker...

Thanks again for your help,

sugarflux