MapForums

function TMapPoint.CalcInCircle(CenterLat, CenterLon: double; Streets: TStrings; out Distance, Angle: integer): boolean;
var
   Lat, Lon: double;
   Radius: double;         // radius of the circle in degree
   Circum: integer;        // circumfence of the circle in Distance
   Count:  integer;        // the amount of points to calculate on the circumfence
   AngleInc: integer;      // angle increments in degree per calculation
begin
   Distance := DistanceRes;
   while Distance <= MaxDistance do begin
      Radius   := 1 / 60 / 1852 * Distance;
      Circum   := Trunc(Distance * 2 * PI);
      Count    := Circum div DistanceRes;
      AngleInc := 360 div Count;
      if AngleInc <= 0 then begin
         Result := False;
         Exit;
      end;
      Angle := 0;
      while Angle < 360 do begin
         CalcXY(CenterLat, CenterLon, Angle, Radius, Lat, Lon);
         Result := FindAddr(Lat, Lon, Streets);
         if Result then
            Exit;
         Inc(Angle, AngleInc);
      end;
      Inc(Distance, DistanceRes);
   end;
   Result := False;
end;

procedure TMapPoint.CalcXY(centerLat, centerLon, Angle, Radius: double; out Lat, lon: double);
var
   a, b, c, r: double;
begin
   {                       B
                         / |
                       /   |
                     /     |
                   /       |
               c /         | a
               /           |
             /             |
           /               |
         /_________________|
       A         b          C

       given A en c
       a = c * sin(A)
       b = c * cos(A)

       A == 0 is direction East in this drawing
       a = Latitude offset
       b = Longitude offset
       c = Radius of circle   }

   r := DegToRad(Angle);
   c := Radius;
   a := c * Sin(r);
   b := c * Cos(r) / Cos(DegToRad(centerLat));  // correct longitude for circle
   Lat := CenterLat + a;
   Lon := CenterLon + b;
end;