Welcome to MapForums!

Register, sign in, or use Facebook Connect above to join in and participate in the forum.

When you are signed in, this message, the ads in this row, and the red-underlined link ads all go away.

Subscribe to receive our newsletter.
Subscribe Unsubscribe
Results 1 to 2 of 2

When I enter just a zipcode in MapPoint, it return....

This is a discussion on When I enter just a zipcode in MapPoint, it return.... within the MapPoint Desktop Discussion forums, part of the Map Forums category; When I enter just a zipcode in MapPoint, it returns <Zipcode>, <State>, <Country> but not the city. Is it possible ...

  1. #1
    Anonymous is offline Senior Member Black Belt
    Join Date
    Jul 2002
    Posts
    5,137
    When I enter just a zipcode in MapPoint, it returns <Zipcode>, <State>, <Country> but not the city. Is it possible to get this information somehow?

    For example, I enter 46038 in MapPoint and search for it. MapPoint returns "46038, Indiana, United States". I cannot determine the city from StreetAddress object because it is set to nothing in this instance. Is there way to get the city for this zipcode? (which is Fishers in this case).

  2. #2
    Walt Cygan is offline Senior Member Green Belt
    Join Date
    Aug 2002
    Posts
    124
    I don't remember where this code originally came from (Gilles Kohl?), but here it is. It returns "Fishers area" for 46038.
    <pre>
    Private Sub cmdGetCity_Click()
    Dim oMap As MapPointCtl.Map
    Dim oCityLoc As MapPointCtl.Location

    'Set the map object to the current map
    Set oMap = ctlMapPoint.ActiveMap

    Dim zipCode As String
    zipCode = txtZip.Text

    Set oCityLoc = FindCityForZipCode(zipCode, oMap)
    If Not (Nothing Is oCityLoc) Then
    txtCity = oCityLoc.Name
    Else
    txtCity = "Couldn't find city for this ZIP Code."
    End If

    End Sub

    Function FindCityForZipCode(strZip As String, oMap As MapPointCtl.Map) As MapPointCtl.Location
    Dim oZipLoc As MapPointCtl.Location
    Dim oZipResults As MapPointCtl.FindResults

    Set oZipResults = oMap.FindAddressResults(, , , , strZip, "USA")

    ' If itís not a good match, then donít accept it
    If geoFirstResultGood = oZipResults.ResultsQuality Then
    Set oZipLoc = oZipResults(1)
    Else
    Exit Function
    End If

    ' Must be a match to a Post Code (US ZIP Code)
    If Not (geoShowByPostal1 = oZipLoc.Type) Then
    Exit Function
    End If

    ' Go to the ZIP Code location on the map to hit test
    oZipLoc.GoTo
    Dim x As Integer
    Dim Y As Integer
    x = oMap.LocationToX(oZipLoc)
    Y = oMap.LocationToY(oZipLoc)

    ' Find all geographic entities at that point
    Dim oContext As MapPointCtl.FindResults
    Set oContext = oMap.ObjectsFromPoint(x, Y)

    ' Return the city at that point (if any)
    For Each obj In oContext
    If geoShowByCity = obj.Type Then
    Set FindCityForZipCode = obj
    Exit Function
    ElseIf geoShowByDefault = obj.Type Then
    Set FindCityForZipCode = obj
    End If
    Next obj

    End Function
    </pre>


    - Walt Cygan


Thread Information

Users Browsing this Thread

There are currently 1 users browsing this thread. (0 members and 1 guests)

Similar Threads

  1. Can you enter GPS coordinates and make a pushpin?
    By tonyc789698 in forum MapPoint Desktop Discussion
    Replies: 3
    Last Post: 11-26-2004, 08:35 PM
  2. Can Mappoint 3.0 SDK return Latitude Longitude coordinates?
    By Anonymous in forum MapPoint Desktop Discussion
    Replies: 1
    Last Post: 01-27-2004, 05:56 PM
  3. newbie wants help in getting mappoint to return coordinates
    By Anonymous in forum MapPoint Desktop Discussion
    Replies: 1
    Last Post: 05-02-2003, 02:36 PM
  4. MapPoint 2002 appears to already have zipcode boun....
    By Anonymous in forum MapPoint Desktop Discussion
    Replies: 1
    Last Post: 07-30-2002, 12:43 PM
  5. Is it possible to enter a City or Zip Code, and re....
    By Anonymous in forum MapPoint Desktop Discussion
    Replies: 3
    Last Post: 06-04-2002, 04:42 PM

Tags for this Thread

Posting Permissions

  • You may not post new threads
  • You may not post replies
  • You may not post attachments
  • You may not edit your posts
  •  


1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25